Recherche de site Web

Pourquoi j'utilise le langage de programmation D pour les scripts

Le langage de programmation D est surtout connu comme langage de programmation système, mais c'est également une excellente option pour les scripts.

Le langage de programmation D est souvent présenté comme un langage de programmation système en raison de ses capacités de typage statique et de métaprogrammation. Cependant, c'est aussi un langage de script très productif.

Python est couramment choisi pour les scripts en raison de sa flexibilité en matière d'automatisation de tâches et de prototypage rapide d'idées. Cela rend Python très attrayant pour les administrateurs système, les gestionnaires et les développeurs en général pour automatiser des tâches récurrentes qu'ils pourraient autrement devoir effectuer manuellement.

Il est raisonnable de s’attendre à ce que tout autre langage d’écriture de script possède ces caractéristiques et capacités Python. Voici deux raisons pour lesquelles je pense que D est une bonne option.

1. D est facile à lire et à écrire

En tant que langage de type C, D devrait être familier à la plupart des programmeurs. Quiconque utilise JavaScript, Java, PHP ou Python connaîtra D.

Si D n’est pas déjà installé, installez un compilateur D afin de pouvoir exécuter le code D dans cet article. Vous pouvez également utiliser l'éditeur D en ligne.

Voici un exemple de code D qui lit les mots d'un fichier nommé words.txt et les imprime sur la ligne de commande :

open
source
is
cool

Écrivez le script en D :

#!/usr/bin/env rdmd
// file print_words.d

// import the D standard library
import std;

void main(){
    // open the file
     File("./words.txt")

         //iterate by line
        .byLine

        // print each number
        .each!writeln;
}

Ce code est préfixé par un shebang qui exécutera le code à l'aide de rdmd, un outil fourni avec le compilateur D pour compiler et exécuter du code. En supposant que vous utilisez Unix ou Linux, avant de pouvoir exécuter ce script, vous devez le rendre exécutable à l'aide de la commande chmod :

chmod u+x print_words.d

Maintenant que le script est exécutable, vous pouvez l'exécuter :

./print_words.d

Cela devrait afficher ce qui suit sur votre ligne de commande :

open
source
is
cool

Toutes nos félicitations! Vous avez écrit votre premier script D. Vous pouvez voir comment D vous permet d'enchaîner des fonctions en séquence pour rendre la lecture du code naturelle, semblable à la façon dont vous réfléchissez aux problèmes dans votre esprit. Cette fonctionnalité fait de D mon langage de programmation préféré.

Essayez d'écrire un autre script : un responsable d'une organisation à but non lucratif dispose d'un fichier texte de dons avec chaque montant sur des lignes distinctes. Le gérant souhaite additionner les 10 premiers dons et imprimer les montants :

#!/usr/bin/env rdmd
// file sum_donations.d

import std;

void main()
{
    double total = 0;

    // open the file
    File("monies.txt")

         // iterate by line
        .byLine

         // pick first 10 lines
        .take(10)

        // remove new line characters (\n)
        .map!(strip)

         // convert each to double
        .map!(to!double)

        // add element to total
        .tee!((x) { total += x; })

        // print each number
        .each!writeln;

    // print total
    writeln("total: ", total);
}

L'opérateur ! utilisé avec each est la syntaxe d'un argument de modèle.

2. D est idéal pour le prototypage rapide

D est flexible pour assembler du code très rapidement et le faire fonctionner. Sa bibliothèque standard est riche de fonctions utilitaires permettant d'effectuer des tâches courantes, telles que la manipulation de données (JSON, CSV, texte, etc.). Il est également livré avec un riche ensemble d'algorithmes génériques pour itérer, rechercher, comparer et muter les données. Ces algorithmes intelligemment conçus sont orientés vers le traitement des séquences en définissant des interfaces génériques basées sur des plages.

Le script ci-dessus montre comment le chaînage des fonctions dans D fournit l'essentiel du traitement séquentiel et de la manipulation des données. Un autre attrait de D est son écosystème croissant de packages tiers pour effectuer des tâches courantes. Un exemple est la facilité avec laquelle il est possible de créer un serveur Web simple à l'aide du framework Web Vibe.d. Voici un exemple :

#!/usr/bin/env dub
/+ dub.sdl:
dependency "vibe-d" version="~>0.8.0"
+/
void main()
{
    import vibe.d;
    listenHTTP(":8080", (req, res) {
        res.writeBody("Hello, World: " ~ req.path);
    });
    runApplication();
}

Cela utilise le gestionnaire de packages D officiel, Dub, pour récupérer le framework Web vibe.d à partir du référentiel de packages D. Dub s'occupe du téléchargement du package Vibe.d, puis de la compilation et du démarrage d'un serveur Web sur le port localhost 8080.

Essayez D

Ce ne sont là que quelques raisons pour lesquelles vous souhaiterez peut-être utiliser D pour écrire des scripts.

D est un excellent langage pour le développement. Il est facile à installer à partir de la page de téléchargement de D, alors téléchargez le compilateur, jetez un œil aux exemples et découvrez D par vous-même.

Articles connexes: